Size of this PNG preview of this SVG file: 450 × 315 pixels. Other resolutions: 320 × 224 pixels | 640 × 448 pixels | 1,024 × 717 pixels | 1,280 × 896 pixels | 2,560 × 1,792 pixels.
Original file (SVG file, nominally 450 × 315 pixels, file size: 109 KB)
This is a file from the Wikimedia Commons. Information from its description page there is shown below.
Commons is a freely licensed media file repository. You can help.
Commons is a freely licensed media file repository. You can help.
Summary
| Description |
English: This shows how Planck's model predicts that oscillators with "photon" constrained-energies ε ≡ hν = hc/λ greater than kT get significantly frozen out of the black body mix, thus solving the ultraviolet catastrophe to which the Rayleigh-Jeans model gave birth. This freeze-out may be explained if (for whatever reason) "quantum oscillators" exist only in packets with energy/frequency & momentum/spatial-frequency linked by the constant h = E/ν = p/g = 2πL.
The probability of an oscillator having photons is given by The energy contribution of an oscillator with photons is given by The average black body energy is the sum of contributions from all oscillators. |
| Date | |
| Source | Isaac, Arun (2016-11-01). Black body energy as a sum of photon oscillator energies (English). systemreboot.net. Retrieved on 2025-11-23. |
| Author | Arun Isaac |
| SVG development | |
| gnuplot source | click to expand
#! /usr/bin/env gnuplot
# This work is in the public domain.
#
# It was completed by Arun I in 2016.
#
# Though you are not legally obliged to do so, I would appreciate it
# if you credit me for this work by not removing this notice, and
# hopefully linking to my blog post at
# https://systemreboot.net/post/black-body-energy-as-a-sum-of-photon-oscillator-energies
# Base filename for output files
filename='blackbody-energies'
# Set terminal and output file
set term epslatex color colortext standalone
set output sprintf('%s.tex', filename)
# Axes' properties, title and key
set xrange [-0.01:5]
set yrange [0:1.05]
set mxtics 5
set ytics 0.2
set mytics 4
set xlabel '$ h\nu/kT $'
set ylabel 'Average oscillator energy (in units of $ kT $)'
set title "Planck's solution as a freeze-out of\nphoton oscillator-energies as $ h\\nu/kT \\to \\infty $"
unset key
# Line styles
set style line 1 lc 'blue' dt 4
set style line 2 lc 'red' dt 4
set style line 3 lc 'dark-yellow' dt 4
set style line 4 lc 'forest-green' dt 4
# Labels
set arrow from graph 0, first 1 to graph 1, first 1 nohead lc 'black' dt 6
set label '$ E_{\textrm{\tiny avg}}^{\textrm{\tiny Rayleigh}} = kT $' at graph 1, first 1 right offset graph -0.05, -0.05
set label '\footnotesize $ h\nu $' at 1.4, 0.15 tc ls 1
set label '\footnotesize $ 2h\nu $' at 1, 0.33 tc ls 2
set label '\footnotesize $ 3h\nu $' at 0.8, 0.45 tc ls 3
set label '\footnotesize $ 4h\nu $' at 0.65, 0.53 tc ls 4
set label '$ E_{\textrm{\tiny avg}}^{\textrm{\tiny Planck}} $' at 0.6, 0.8
# Expressions to plot
En(x,n) = n*x*exp(-n*x)*(1-exp(-x))
yN(x,N) = sum [n=1:N] En(x,n)
plot x/(exp(x) - 1) with lines lc 'black', \
for [N=1:4] yN(x,N) with lines ls N
# Convert tex -> pdf -> svg
set output
system(sprintf('pdflatex %s.tex && pdf2svg %s.pdf %s.svg', filename, filename, filename))
|
Licensing
Arun Isaac, the copyright holder of this work, hereby publishes it under the following license:
This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.
Attribution:
Arun Isaac
- You are free:
- to share – to copy, distribute and transmit the work
- to remix – to adapt the work
- Under the following conditions:
- attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
- share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
File history
Click on a date/time to view the file as it appeared at that time.
| Date/Time | Thumbnail | Dimensions | User | Comment | |
|---|---|---|---|---|---|
| current | 22:58, 31 October 2016 | | 450 × 315 (109 KB) | Arunisaac | User created page with UploadWizard |
File usage
The following page uses this file:
Global file usage
The following other wikis use this file:
- Usage on sr.wikipedia.org
